home *** CD-ROM | disk | FTP | other *** search
/ Brotikasten / BROTCD01.iso / geos / geos173.d64 / pRINT dATES (.txt) < prev    next >
Commodore BASIC  |  1995-08-07  |  4KB  |  169 lines
  1. 10 POKE644,128:POKE56,128:CLR:POKE53280,2:POKE53281,0:PRINT"[158]";CHR$(14)
  2. 15 PRINT"[147]":PRT=0:FL=0
  3. 20 DIMTK(128),SC(128):DIMDATE$(127)
  4. 25 N=5:FORX=1TO8:P(X)=N:N=N+32:NEXTX
  5. 30 FORX=1TO9:READN:DB$=DB$+CHR$(N):NEXTX
  6. 35 PRINT"[159][147]";TAB(15);"           [146]"
  7. 40 PRINTTAB(15);" [205][193][201][206] [205][197][206][213] [146]"
  8. 45 PRINTTAB(15);"           [146][158]"
  9. 50 PRINTTAB(8);"[198]1 = [207]PEN DATEBOOK FILE"
  10. 55 PRINTTAB(8);"[198]3 = [196]ISPLAY/PRINT ENTRIES"
  11. 60 PRINTTAB(8);"[198]5 = [208]RINT ENTIRE DATEBOOK"
  12. 65 PRINTTAB(8);"[198]7 = [209]UIT TO DESKTOP"
  13. 70 GETA$:IFA$=""THEN70 
  14. 75 IFA$=CHR$(133)THENGOSUB100:GOTO35
  15. 80 IFA$=CHR$(134)THENGOSUB370:GOTO35
  16. 85 IFA$=CHR$(135)THENGOSUB640:GOTO35
  17. 90 IFA$=CHR$(136)THEN825
  18. 95 GOTO70 
  19. 100 NUMENT=0:INPUT"[147]DRIVE";DR
  20. 105 IFDR<8ORDR>9THEN100
  21. 110 OPEN15,DR,15:PRINT#15,"I0":INPUT#15,EN$,EM$,ET$,ES$:CLOSE15
  22. 115 IFEN$="00"THEN135
  23. 120 PRINT"[147]";TAB(10);EN$,EM$:PRINTTAB(8);"HIT ANY KEY FOR MAIN MENU"
  24. 125 GETA$:IFA$=""THEN125
  25. 130 RETURN
  26. 135 PRINT"[147]";TAB(7);"SEARCHING FOR DATEBOOK FILE"
  27. 140 OPEN15,DR,15:OPEN5,DR,5,"#"
  28. 145 FORS=1TO19:PRINT#15,"U1";5;0;18;S
  29. 150 FORF=1TO8:NAME$="":PRINT#15,"B-P";5;P(F)
  30. 155 FORI=1TO9:GET#5,A$:IFA$=""THENA$=CHR$(0)
  31. 160 A=ASC(A$):IFA>127THENA=A-128
  32. 165 IFA=34THENA=63
  33. 170 NAME$=NAME$+CHR$(A):NEXT:IFNAME$=DB$THEN200
  34. 175 NEXT:NEXT
  35. 180 CLOSE2:CLOSE15:PRINT"[147]";TAB(7);"DATEBOOK FILE NOT ON DISK"
  36. 185 PRINT"CHECK DISK; HIT ANY KEY TO CONTINUE"
  37. 190 GETA$:IFA$=""THEN190
  38. 195 RETURN
  39. 200 PRINT#15,"B-P";5;P(F)-2:GET#5,T$:GET#5,S$:T=ASC(T$):S=ASC(S$)
  40. 205 PRINT#15,"U1";5;0;T;S
  41. 210 GET#5,A$:GET#5,A$:X=1
  42. 215 GET#5,A$:IFA$=""THEN240
  43. 220 IFST<>0THEN240
  44. 225 TK(X)=ASC(A$)
  45. 230 GET#5,A$:SC(X)=ASC(A$+CHR$(0))
  46. 235 X=X+1:GOTO215
  47. 240 PRINT"[147]";TAB(11);"FOUND DATEBOOK FILE"
  48. 245 PRINTTAB(11);"READING ENTRY DATES"
  49. 250 T=TK(1):S=SC(1):X=1
  50. 255 PRINT#15,"U1";5;0;T;S
  51. 260 GET#5,A$:T=ASC(A$+CHR$(0))
  52. 265 GET#5,A$:S=ASC(A$+CHR$(0))
  53. 270 GET#5,A$
  54. 275 FORI=1TO6
  55. 280 GET#5,A$:IFI=1ANDA$=""THENNUMENT=X:CLOSE5:CLOSE15:RETURN
  56. 285 IFA$=""THENA$=CHR$(0)
  57. 290 GOSUB340
  58. 295 ONIGOSUB305,315,330,335,335,335
  59. 300 NEXTI:DATE$(X)=DA$:X=X+1:GOTO275
  60. 305 A$=STR$(ASC(A$)):DA$=RIGHT$(A$,LEN(A$)-1):IFLEN(DA$)<2THENDA$="0"+DA$
  61. 310 RETURN
  62. 315 A$=STR$(ASC(A$)+1):A$=RIGHT$(A$,LEN(A$)-1)
  63. 320 IFLEN(A$)<2THENA$="0"+A$
  64. 325 DA$=A$+"/"+DA$:RETURN
  65. 330 DA$=DA$+"/"+CHR$(ASC(A$)+48):RETURN
  66. 335 DA$=DA$+CHR$(ASC(A$)+48):RETURN
  67. 340 IFST=0THENRETURN
  68. 345 PRINT#15,"U1";5;0;T;S
  69. 350 GET#5,A$:T=ASC(A$+CHR$(0))
  70. 355 GET#5,A$:S=ASC(A$+CHR$(0))
  71. 360 RETURN
  72. 365 CLOSE5:CLOSE15:RETURN
  73. 370 IFNUMENT<>0THEN405
  74. 375 PRINT"[147]";TAB(8);"[206][207] [197][206][212][210][217] [196][193][212][197][211] [201][206] [205][197][205][207][210][217]"
  75. 380 PRINT"";TAB(9);"[195]HOOSE [198]1 AT MAIN MENU"
  76. 385 PRINTTAB(9);"TO OPEN DATEBOOK FILE."
  77. 390 PRINT"";TAB(7);"[200]IT ANY KEY TO CONTINUE..."
  78. 395 GETA$:IFA$=""THEN395
  79. 400 RETURN
  80. 405 PTR=1
  81. 410 PRINT"[147]":FORX=PTRTOPTR+4
  82. 415 IFX>NUMENTTHENNEXTX:GOTO435
  83. 420 IFX+5>NUMENTTHENPRINT"";TAB(5);DATE$(X):NEXTX:GOTO435
  84. 425 PRINT"";TAB(5);DATE$(X);TAB(25);DATE$(X+10)
  85. 430 NEXTX
  86. 435 PRINT"ENTER  MO/DA/YR [146] TO DISPLAY/PRINT ENTRY"
  87. 440 PRINT"ENTER  MO/YR [146] TO PRINT ENTIRE MONTH"
  88. 445 PRINT"HIT  RETURN [146] FOR MORE ENTRY DATES"
  89. 450 PRINT"ENTER  M [146] FOR MAIN MENU":A$=""
  90. 455 INPUT"";A$
  91. 460 IFA$="M"THEN RETURN
  92. 465 IFLEN(A$)=8THENGOSUB545:GOTO410
  93. 470 IFLEN(A$)=5THENGOSUB510:GOTO410
  94. 475 IFA$<>""THEN410
  95. 480 IFX+9>NUMENTTHENGOSUB490:GOTO405
  96. 485 PTR=X+10:GOTO410
  97. 490 PRINT"[147]";TAB(13);"[206][207] [205][207][210][197] [197][206][212][210][201][197][211]"
  98. 495 PRINTTAB(8);"[200]IT ANY KEY TO CONTINUE..."
  99. 500 GETA$:IFA$=""THEN500
  100. 505 RETURN
  101. 510 N=1:FORX=1TONUMENT
  102. 515 IFLEFT$(DATE$(X),2)<>LEFT$(A$,2)THEN535
  103. 520 IFMID$(DATE$(X),9,2)<>RIGHT$(A$,2)THEN535
  104. 525 IFN=1THENBEG=X+1
  105. 530 N=X+1:PRINTDATE$(N-1)
  106. 535 NEXTX:IFN=1THENGOSUB580:RETURN
  107. 540 FINISH=N:GOSUB650:RETURN
  108. 545 N=1:FORX=1TO NUMENT
  109. 550 IFLEFT$(DATE$(X),5)<>LEFT$(A$,5)THEN570
  110. 555 IFRIGHT$(DATE$(X),2)<>RIGHT$(A$,2)THEN570
  111. 560 IFN=1THENBEG=X+1
  112. 565 N=X+1:PRINTDATE$(N-1)
  113. 570 NEXTX:IFN=1THENGOSUB580:RETURN
  114. 575 FINISH=N:GOSUB650:RETURN
  115. 580 PRINT"[147]";TAB(6);"NO ENTRIES FOR DATE ENTERED"
  116. 585 PRINTTAB(8);"HIT ANY KEY TO CONTINUE"
  117. 590 GETA$:IFA$=""THEN590
  118. 595 RETURN
  119. 600 GOSUB775
  120. 605 PRINT"[147]";TAB(15);DATE$(X-1);""
  121. 610 PRINTD$
  122. 615 PRINTTAB(13);"HIT P TO PRINT"
  123. 617 PRINTTAB(13);"HIT Q TO QUIT"
  124. 620 PRINTTAB(6);"OR ANY OTHER KEY TO CONTINUE"
  125. 625 GETA$:IFA$=""THEN625
  126. 627 IFA$="P"THENGOSUB810
  127. 630 IFA$="Q"THENRETURN
  128. 635 RETURN
  129. 640 IFNUMENT=0THENGOSUB375:RETURN
  130. 645 FL=1:BEG=2:FINISH=NUMENT:GOSUB650:FL=0:RETURN
  131. 650 PRINT"[147]";TAB(11);"[212][210][193][206][211][204][193][212][201][206][199] [193][211][195][201][201]"
  132. 655 IFFL<>1THEN670
  133. 660 PRINTTAB(14);"[193][206][196] [208][210][201][206][212][201][206][199]"
  134. 665 PRINTTAB(13);"HIT Q TO QUIT"
  135. 670 OPEN15,DR,15:OPEN5,DR,5,"#"
  136. 675 FORX=BEG TO FINISH
  137. 680 T=TK(X):S=SC(X):D$=""
  138. 685 PRINT#15,"U1";5;0;T;S
  139. 690 GET#5,A$:T=ASC(A$+CHR$(0))
  140. 695 GET#5,A$:S=ASC(A$+CHR$(0))
  141. 700 GET#5,A$:IFA$=""THEN725
  142. 705 IFASC(A$)=141THENA$=CHR$(13)
  143. 710 GOSUB750
  144. 715 IFLEN(D$)=254THEN725
  145. 720 D$=D$+A$:GOTO700
  146. 725 IFFL<>1THEN740
  147. 730 GETX$:IFX$="Q"THENCLOSE5:CLOSE15:RETURN
  148. 735 GOSUB775:GOSUB810:GOTO745
  149. 740 GOSUB600:IFA$="Q"THENCLOSE5:CLOSE15:RETURN
  150. 745 NEXTX:CLOSE5:CLOSE15:RETURN
  151. 750 IFST=0THENRETURN
  152. 755 PRINT#15,"U1";5;0;T;S
  153. 760 GET#5,A$:T=ASC(A$+CHR$(0))
  154. 765 GET#5,A$:S=ASC(A$+CHR$(0))
  155. 770 RETURN
  156. 775 L=LEN(D$):DD$="":FORCP=1TOL:CC$=MID$(D$,CP,1):CA=ASC(CC$)
  157. 780 IFCA>96ANDCA<123THEN795
  158. 785 IFCA>64ANDCA<91THEN800
  159. 790 DD$=DD$+CC$:GOTO805
  160. 795 CA=CA-32:CC$=CHR$(CA):GOTO790
  161. 800 CA=CA+32:CC$=CHR$(CA):GOTO790
  162. 805 NEXT:D$=DD$:RETURN
  163. 810 PRT=1:OPEN4,4,7:PRINT#4," ":PRINT#4,DATE$(X-1)
  164. 815 PRINT#4,D$:CLOSE4:RETURN
  165. 820 GOTO820
  166. 825 IFPRT=1THENOPEN4,4,0:PRINT#4,CHR$(12):CLOSE4
  167. 830 SYS49893:SYS49708:NEW
  168. 835 DATA68,97,116,101,32,66,111,111,107
  169.